حالت‌های WIFI

ESP32 در دو حالت مختلف WIFI قابل استفاده است.

حالت ایستگاه (STA)

در حالت STA یا station، ESP32 به عنوان یک ایستگاه WIFI با مشتری عمل می‌کند. ترتیب در اینجا نشان داده شده‌است:

در این حالت ESP32 برای دسترسی به شبکه‌ی WIFI باید SSID و رمز عبور را بداند (در یک شبکه‌ی بدون امنیت نیازی به رمز عبور نیست).

ESP32 با استفاده از روترهای داخلی DHCP با آدرس IP شبکه ارائه می‌شود. سپس با استفاده از آن آدرس قابل دسترسی است. همچنین می‌توان یک آدرس IP ثابت به ESP32 اختصاص داد که اگر از آن به عنوان یک سرور وب استفاده کنید که تغییر آدرس IP باعث ایجاد مشکل برای سایر سرویس گیرندگان می‌شود، مفید خواهد بود.

حالت دسترسی نرم‌افزار (AP)

در حالت Soft Access Point یا AP، ESP32 اتصال WIFI را برای دستگاه‌های خارجی فراهم می‌کند. این دستگاه‌ها می‌توانند رایانه، تلفن، رایانه‌ی لوحی، دستگاه‌های اینترنت اشیاء یا حتی سایر ESP32 باشند که در حالت STA پیکربندی شده‌اند.

ESP32 می‌تواند حداکثر از پنج دستگاه خارجی در حالت AP پشتیبانی کند. آدرس IP پیش‌فرض آن ۱۹۲.۱۶۸.۴.۱ است و خدمات DHCP را به دستگاه‌های متصل خارجی ارائه می‌دهد. اگر با دستگاه‌های موجود مغایرت داشته باشد، آدرس IP پیش‌فرض قابل تغییر است. این کار اجازه می‌دهد تا ESP32، شبکه‌ی مستقل از هر شبکه‌ی WIFI موجود را ایجاد کند. می‌توانید شبکه را با رمز عبور ایمن کرده و SSID (نام شبکه) را انتخاب کنید. اتفاقاً،‌ این حرکت به عنوان یک نقطه دسترسی “Soft” شناخته می‌شود زیرا ESP32 اتصال سخت‌افزاری به اینترنت یا سایر شبکه‌های موجود را فراهم نمی‌کند.

WIFI SCANNER

اولین طرحی که ما بررسی خواهیم‌کرد WIFI SCSNNER است. همان‌طور که از نام آن پیدا است، این برنامه شبکه‌های WIFI محلی را اسکن می‌کند. سپس نتایج را روی مانیتور سریال چاپ می‌کند. نتایج شامل SSID شبکه (نام شبکه)، قدرت سیگنال در dBm و یک نشانگر در صورت امنیت شبکه است.

پیدا کردن برنامه‌های مثال این طرح، همراه با سایر برنامه‌های نمایشی که بررسی خواهیم‌کرد، به شرح زیر قابل دسترسی است:

·         Arduino IDE را باز کنید.

·         منوی File را از نوار منوی بالای IDE انتخاب کنید.

·         به پایین به عنوان مثال پیمایش کنید. منوی فرعی باز می‌شود.

·         به پایین مثال‌ها بروید تا بخشی از مثال‌ها را برای ESP32 پیدا کنید. این براساس برد ESP32 که شما انتخاب کرده‌اید، برچسب‌گذاری می‌شود، همان بردی که من استفاده می‌کنم می‌گوید Examples برای Node 32s.

·         تعدادی از موارد منو را در زیر این مشاهده خواهیدکرد. هریک از زیر منوی خود را با یک یا چند مثال دارد.

WIFISCAN را بارگیری کنید

مثالی که اکنون می‌خواهیم استفاده کنیم تحت WIFI است و WIFISCAN نام دارد.

 *  This sketch demonstrates how to scan WiFi networks.

 *  The API is almost the same as with the WiFi Shield library,

 *  the most obvious difference being the different file you need to include:

 */

#include "WiFi.h"

 

void setup()

{

    Serial.begin(115200);

 

    // Set WiFi to station mode and disconnect from an AP if it was previously connected

    WiFi.mode(WIFI_STA);

    WiFi.disconnect();

    delay(100);

 

    Serial.println("Setup done");

}

 

void loop()

{

    Serial.println("scan start");

 

    // WiFi.scanNetworks will return the number of networks found

    int n = WiFi.scanNetworks();

    Serial.println("scan done");

    if (n == 0) {

        Serial.println("no networks found");

    } else {

        Serial.print(n);

        Serial.println(" networks found");

        for (int i = 0; i < n; ++i) {

            // Print SSID and RSSI for each network found

            Serial.print(i + 1);

            Serial.print(": ");

            Serial.print(WiFi.SSID(i));

            Serial.print(" (");

            Serial.print(WiFi.RSSI(i));

            Serial.print(")");

            Serial.println((WiFi.encryptionType(i) == WIFI_AUTH_OPEN)?" ":"*");

            delay(10);

        }

    }

    Serial.println("");

 

    // Wait a bit before scanning again

    delay(5000);

}

این کد از کتابخانه‌ی WIFI استفاده می‌کند و کاملاً قابل توضیح است. دستور Wifi.scanNetworks شبکه‌های موجود را اسکن کرده و آن‌ها را در یک آرایه وارد می‌کند. سپس آرایه برای تولید نتایج اسکن گام برمی‌دارد. کد را در ESP32 بارگذاری کنید. به یاد داشته‌باشید که درصورت لزوم دکمه‌ی BOOT را پایین نگه‌دارید. سپس مانیتور سریال خود را باز کنید (مطمئن شوید که روی bude ۱۱۵۲۰۰  تنظیم شده‌باشد).

هنگامی که مانیتور را برای اولین بار باز می‌کنید، احتمال اینکه gibberish را مشاهده کنید وجود دارد. این به این معنا است که سیگنال سریال به درستی همگام نشده است. اکنون باید اسکن شبکه‌های موجود در مکان خود را مشاهده کنید.

ردیاب Brownout فعال شده

هنگام استفاده از رادیوی داخلی برای WIFI یا بلوتوث، هنگام تنظیم مجدد ESP32 ممکن است با پیام Brownout Detector مواجه شوید. به‌طور کلی به این معناست که ESP32 جریان کافی دریافت نمی‌کند. این پیام معمولاً دلیلی برای هشدار نیست و می‌توانید به صورت عادی پیش بروید. درصورت بروز مشکل، سعی کنید کابل‌های USB را تغییر دهید یا از USB hub تغذیه شده استفاده کنید تا جریان اضافی را برای ESP32 تأمین کنید.

WIFI Access Point

مثال بعدی که بررسی خواهیم‌کرد از ESP32 در حالت AP یا Soft Access Point استفاده می‌کند. این مثال را با مثال قبلی در زیر منوی  WIFI خواهید یافت که WIFI Access Point نامیده می‌شود. این برنامه ESP32 را درحالت AP قرار می‌دهد و سپس یک وب سرور و صفحه وب بسیار ساده ایجاد می‌کند. صفحه وب دارای دو پیوند است و از این پیوندها می‌توان برای کنترل وضعیت LED در ESP32 استفاده کرد.

  WiFiAccessPoint.ino creates a WiFi access point and provides a web server on it.

 

  Steps:

  1. Connect to the access point "yourAp"

  2. Point your web browser to http://192.168.4.1/H to turn the LED on or http://192.168.4.1/L to turn it off

     OR

     Run raw TCP "GET /H" and "GET /L" on PuTTY terminal with 192.168.4.1 as IP address and 80 as port

 

  Created for arduino-esp32 on 04 July, 2018

  by Elochukwu Ifediora (fedy0)

*/

 

#include <WiFi.h>

#include <WiFiClient.h>

#include <WiFiAP.h>

 

#define LED_BUILTIN 2   // Set the GPIO pin where you connected your test LED or comment this line out if your dev board has a built-in LED

 

// Set these to your desired credentials.

const char *ssid = "yourAP";

const char *password = "yourPassword";

 

WiFiServer server(80);

 

 

void setup() {

  pinMode(LED_BUILTIN, OUTPUT);

 

  Serial.begin(115200);

  Serial.println();

  Serial.println("Configuring access point...");

 

  // You can remove the password parameter if you want the AP to be open.

  WiFi.softAP(ssid, password);

  IPAddress myIP = WiFi.softAPIP();

  Serial.print("AP IP address: ");

  Serial.println(myIP);

  server.begin();

 

  Serial.println("Server started");

}

 

void loop() {

  WiFiClient client = server.available();   // listen for incoming clients

 

  if (client) {                             // if you get a client,

    Serial.println("New Client.");           // print a message out the serial port

    String currentLine = "";                // make a String to hold incoming data from the client

    while (client.connected()) {            // loop while the client's connected

      if (client.available()) {             // if there's bytes to read from the client,

        char c = client.read();             // read a byte, then

        Serial.write(c);                    // print it out the serial monitor

        if (c == '\n') {                    // if the byte is a newline character

 

          // if the current line is blank, you got two newline characters in a row.

          // that's the end of the client HTTP request, so send a response:

          if (currentLine.length() == 0) {

            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)

            // and a content-type so the client knows what's coming, then a blank line:

            client.println("HTTP/1.1 200 OK");

            client.println("Content-type:text/html");

            client.println();

 

            // the content of the HTTP response follows the header:

            client.print("Click <a href=\"/H\">here</a> to turn ON the LED.<br>");

            client.print("Click <a href=\"/L\">here</a> to turn OFF the LED.<br>");

 

            // The HTTP response ends with another blank line:

            client.println();

            // break out of the while loop:

            break;

          } else {    // if you got a newline, then clear currentLine:

            currentLine = "";

          }

        } else if (c != '\r') {  // if you got anything else but a carriage return character,

          currentLine += c;      // add it to the end of the currentLine

        }

 

        // Check to see if the client request was "GET /H" or "GET /L":

        if (currentLine.endsWith("GET /H")) {

          digitalWrite(LED_BUILTIN, HIGH);               // GET /H turns the LED on

        }

        if (currentLine.endsWith("GET /L")) {

          digitalWrite(LED_BUILTIN, LOW);                // GET /L turns the LED off

        }

      }

    }

    // close the connection:

    client.stop();

    Serial.println("Client Disconnected.");

  }

}

به‌طور پیش‌فرض SSID نقطه دسترسی “your AP” و رمز عبور “yourPassword” است. درصورت تمایل می‌توانید هر دوی این ثابت‌ها را اصلاح کنید. به‌طور پیش‌فرض آدرس IP سرور وب ۱۸۲.۱۶۸.۴.۱ خواهدبود که آن را برای تست طرح باید بدانید. طرح را در ESP32 بارگیری کرده و دوباره تنظیم کنید. با استفاده از مانیتور سریال می‌توانید تنظیم مجدد را کنترل کنید. اکنون از دستگاهی مانند نوت‌بوک،‌ لپ‌تاپ یا تلفن استفاده کرده و دستگاه‌های WIFI موجود خود را اسکن کنسد. شما باید شبکه‌ی yourAP را در لیست مشاهده کنید. با استفاده از رمز عبور yourPassword با دستگاه خود به شبکه متصل شوید.

پس از برقراری اتصال، یک مرورگر وب را در دستگاه متصل باز کنید و به شماره‌ی ۱۹۲.۱۶۸.۴.۱  بروید. شما باید یک صفحه وب با دو پیوند را ببینید. یکی برای روشن‌کردن LED و دیگری برای خاموش‌کردن آن. روی پیوندها کلیک کنید و LED را که به ESP32 سیم‌کشی کرده‌اید (یا LED تعبیه‌شده روی خود ماژول) مشاهده کنید. باید بتوانید آن را از طریق صفحه وب کنترل کنبد.

این مثال ساده می‌تواند به عنوان پایه‌ای برای کد شما استفاده شود.

Simple Wifi Server

مثال Simple Wifi Server عملکردی مشابه طرح قبلی را انجام می‌دهد. تفاوت در این است که در این حالت ESP32 در حالت STA (ایستگاه) استفاده می‌شود. بنابراین یک وب سرور در شبکه‌ی خود ایجاد می‌کند. می‌توانید LED را از طریق هر رایانه یا دستگاه متصل به شبکه‌ی خود کنترل کنید. این مثال را در زیر منوی WIFI نیز با نام Simple Wifi Server پیدا خواهید کرد.

/*

 WiFi Web Server LED Blink

 

 A simple web server that lets you blink an LED via the web.

 This sketch will print the IP address of your WiFi Shield (once connected)

 to the Serial monitor. From there, you can open that address in a web browser

 to turn on and off the LED on pin 5.

 

 If the IP address of your shield is yourAddress:

 http://yourAddress/H turns the LED on

 http://yourAddress/L turns it off

 

 This example is written for a network using WPA encryption. For

 WEP or WPA, change the Wifi.begin() call accordingly.

 

 Circuit:

 * WiFi shield attached

 * LED attached to pin 5

 

 created for arduino 25 Nov 2012

 by Tom Igoe

 

ported for sparkfun esp32 

31.01.2017 by Jan Hendrik Berlin

 

 */

 

#include <WiFi.h>

 

const char* ssid     = "yourssid";

const char* password = "yourpasswd";

 

WiFiServer server(80);

 

void setup()

{

    Serial.begin(115200);

    pinMode(2, OUTPUT);      // set the LED pin mode

 

    delay(10);

 

    // We start by connecting to a WiFi network

 

    Serial.println();

    Serial.println();

    Serial.print("Connecting to ");

    Serial.println(ssid);

 

    WiFi.begin(ssid, password);

 

    while (WiFi.status() != WL_CONNECTED) {

        delay(500);

        Serial.print(".");

    }

 

    Serial.println("");

    Serial.println("WiFi connected.");

    Serial.println("IP address: ");

    Serial.println(WiFi.localIP());

    

    server.begin();

 

}

 

int value = 0;

 

void loop(){

 WiFiClient client = server.available();   // listen for incoming clients

 

  if (client) {                             // if you get a client,

    Serial.println("New Client.");           // print a message out the serial port

    String currentLine = "";                // make a String to hold incoming data from the client

    while (client.connected()) {            // loop while the client's connected

      if (client.available()) {             // if there's bytes to read from the client,

        char c = client.read();             // read a byte, then

        Serial.write(c);                    // print it out the serial monitor

        if (c == '\n') {                    // if the byte is a newline character

 

          // if the current line is blank, you got two newline characters in a row.

          // that's the end of the client HTTP request, so send a response:

          if (currentLine.length() == 0) {

            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)

            // and a content-type so the client knows what's coming, then a blank line:

            client.println("HTTP/1.1 200 OK");

            client.println("Content-type:text/html");

            client.println();

 

            // the content of the HTTP response follows the header:

            client.print("Click <a href=\"/H\">here</a> to turn the LED on pin 2 on.<br>");

            client.print("Click <a href=\"/L\">here</a> to turn the LED on pin 2 off.<br>");

 

            // The HTTP response ends with another blank line:

            client.println();

            // break out of the while loop:

            break;

          } else {    // if you got a newline, then clear currentLine:

            currentLine = "";

          }

        } else if (c != '\r') {  // if you got anything else but a carriage return character,

          currentLine += c;      // add it to the end of the currentLine

        }

 

        // Check to see if the client request was "GET /H" or "GET /L":

        if (currentLine.endsWith("GET /H")) {

          digitalWrite(2, HIGH);               // GET /H turns the LED on

        }

        if (currentLine.endsWith("GET /L")) {

          digitalWrite(2, LOW);                // GET /L turns the LED off

        }

      }

    }

    // close the connection:

    client.stop();

    Serial.println("Client Disconnected.");

  }

}

قبل از استفاده از این کد باید چند ویرایش انجام دهید:

·         شما باید SSID شبکه‌ی خود را وارد کنید (خط ۳۰).

·         باید رمز شبکه‌ی خود را وارد کنید (خط ۳۱).

·         شما باید دستور pinMode را ویرایش کنید و “۵” را به “۲” تغییر دهید (خط ۳۸).

·         شما باید دستور digitalWrite را ویرایش کنید و “۵” را به “۲” تغییر دهید (خط ۱۰۵).

·         شما باید دستور digitalWrite را ویرایش کنید و “۵” را به “۲” تغییر دهید (خط ۱۰۸).

سه ویرایش اخیر به این دلیل است که متأسفانه نویسنده‌ی طرح، به‌جای استفاده از یک ثابت یا متغیر،‌ انتخاب کد سخت شماره‌های پین GPIO را انتخاب کرده‌است. راه دیگر در این مورد این است که فقط LED را به GPIO5 منتقل کنید و از این ویرایش‌ها جلوگیری کنید.

پس از ویرایش، آن را در ESP32 بارگیری کنید. مانیتور سریال خود را باز کنید و ESP32 را دوباره تنظیم کنید. مانیتور سریال آدرس IP را که ESP32 از سرور DHCP روتر شما اختصاص داده شده نشان می‌دهد. این آدرس را کپی کرده و سپس در مرورگر وب جای‌گذاری کنید. شما باید یک صفحه وب بسیار مشابه صفحه وب نمایش داده شده در آزمایش قبلی را مشاهده کنید. با کلیک برروی پیوندها، LED کنترل می‌شود.

استفاده از بلوتوث

یکی از پیشرفت‌های بزرگی که ESP32 نسبت به مدل قبلی خود یعنی ESP8266 داشته است، قابلیت‌های بلوتوثی یکپارچه‌ی آن است. با بلوتوث، ESP32 قادر است با تعداد زیادی دستگاه بلوتوث ارتباط برقرار کند و تعداد بیشماری از برنامه‌های بالقوه را باز کند.

بلوتوث و BLE در ESP32

ESP32 دارای بلوتوث کلاسیک و BLE یا بلوتوث کم انرژی است. دستگاه می‌تواند به‌عنوان مشتری بلوتوث یا سرور عمل کند. اگر با تفاوت بلوتوث کلاسیک و BLE آشنا نیستید، در اینجا یک توضیح مختصر آورده شده‌است.

بلوتوث کلاسیک ۴.۲

همان‌طور که از نام آن مشخص است، بلوتوث کلاسیک عمر بیشتری دارد و احتمالاً بلوتوثی است که بیشتر با آن آشنایی دارید.

از بلوتوث کلاسیک برای انتقال مداوم داده استفاده می‌شود. می‌تواند برای برنامه‌های صوتی بی‌سیم، وسایل جانبی رایانه مانند MOUSE و صفحه کلید استفاده شود.

بلوتوث کم انرژی

بلوتوث کم انرژی یا به اختصار BLE، داده‌ها را با انفجارهای کوتاه مبادله می‌کند. همان‌طور که از نامش پیداست جریان کمی مصرف می‌کند. این ویژگی BLE را برای سنسورهای از راه دور و دستگاه‌های اینترنت اشیاء ایده‌آل می‌کند زیرا این‌ها تنها به افجار کوتاه نیاز دارند و اغلب از طریق باتری کار می‌کنند. با استفاده از BLE می‌توان محصولاتی را طراحی کرد که به جای ماه‌ها یا روزها، عمر باتری را در سال اندازه‌گیری کنند! یکی دیگر از برنامه‌های عالی برای BLE تبلیغات هدفمند است. به‌عنوان مثال می‌توان به رستورانی اشاره کرد که می‌تواند منوی غذا یا محصولات ویژه‌ی روزانه‌ی خود را برای مشتریان بالقوه‌ی مجاور پخش کند. پروتکل iBeacon اپل نیز از این ویژگی استفاده می‌کند.

سریال به سریال BT

برای آزمایش بلوتوث برروی ESP32 ما از یک طرح آزمایشی ساده استفاده خواهیم‌کرد که نام آن Serial To Serial BT می‌باشد.

licensed, at your option.)

//By Evandro Copercini - 2018

//

//This example creates a bridge between Serial and Classical Bluetooth (SPP)

//and also demonstrate that SerialBT have the same functionalities of a normal Serial

 

#include "BluetoothSerial.h"

 

#if !defined(CONFIG_BT_ENABLED) || !defined(CONFIG_BLUEDROID_ENABLED)

#error Bluetooth is not enabled! Please run `make menuconfig` to and enable it

#endif

 

BluetoothSerial SerialBT;

 

void setup() {

  Serial.begin(115200);

  SerialBT.begin("ESP32test"); //Bluetooth device name

  Serial.println("The device started, now you can pair it with bluetooth!");

}

 

void loop() {

  if (Serial.available()) {

    SerialBT.write(Serial.read());

  }

  if (SerialBT.available()) {

    Serial.write(SerialBT.read());

  }

  delay(20);

}

عملکرد این برنامه تبادل داده‌ها بین سریال مانیتور Arduino IDE و یک پایانه‌ی سریال خارجی بلوتوث است. آنچه روی یک دستگاه نوشته شده توسط دستگاه دیگر خوانده می‌شود و در هر دو جهت کار می‌کند. شما می‌توانید هنگام توسعه‌ی برنامه‌های بلوتوث خود، میزان مفید بودن آن را ببینید.

برای آزمایش طرح، باید نوعی ترمینال بلوتوث سریال داشته باشید. اگر دستگاه اندرویدی دارید می‌توانید از برنامه‌ی Serial Bluetooth Terminal که در Google Play رایگان است استفاده کنید. کاربران دستگاه Apple IOS می‌توانند برنامه‌ی Bluetooth Terminal یا Blue Term را که هر دو در Apple App موجود است، امتحان کنند.

پس از برداشتن ترمینال می‌توانید طرح را بارگیری کرده و دستگاه خود را با ESP32 جفت کنید. به دنبال دستگاهی به نام ESP32test بگردید (در صورت تمایل می‌توانید این نام را با اصلاح خط ۱۷ کد تغییر دهید). اکنون از ترمینال بلوتوث خود برای تایپ کردن چیزی استفاده کنید. شما باید متنی را که تایپ کرده‌اید در سریال مانیتور Arduino IED مشاهده کنید. همچنین می‌توانید متن را در BOX متن سریال مانیتور تایپ کنید. این من باید در ترمینال بلوتوث شما نشان داده‌شود.

ویژگی‌های بیشتر ESP32

همان‌طور که در ابتدای پست بیان شد، ESP32 علاوه‌بر WIFI و بلوتوث، قابلیت‌های بسیاری دارد. بهترین راه برای یادگیری، استفاده از این ویژگی‌ها و اجرای مثال‌های ارائه شده توسط ESPressif است. درست همان‌طور که هنگام یادگیری ویژگی‌های wifi‌ و بلوتوث انجام دادیم. همه‌ی این مثال‌ها را می‌توانید در زیر منوی ESP32 در مثال‌ها پیدا کنید. با برجسته‌سازی این منو، یک زیر منو ظاهر می‌شود که به نوبه‌ی خود حاوی زیر منوهای بیشتری است. در زیر نمونه‌ی کوچکی از این مثال‌ها آورده شده‌است.

Simple Time

یکی از ویژگی‌های ESP32 ساعت داخلی Real Time آن است. مثال Simple Time، که در زیر منوی Time یافت می‌شود، نشان می‌دهد که چگونه می‌توانید ساعت را با استفاده از سرور NTP (پروتکل زمان شبکه) در اینترنت تنظیم کنید.

#include <WiFi.h>

#include "time.h"

 

const char* ssid       = "YOUR_SSID";

const char* password   = "YOUR_PASS";

 

const char* ntpServer = "pool.ntp.org";

const long  gmtOffset_sec = 3600;

const int   daylightOffset_sec = 3600;

 

void printLocalTime()

{

  struct tm timeinfo;

  if(!getLocalTime(&timeinfo)){

    Serial.println("Failed to obtain time");

    return;

  }

  Serial.println(&timeinfo, "%A, %B %d %Y %H:%M:%S");

}

 

void setup()

{

  Serial.begin(115200);

  

  //connect to WiFi

  Serial.printf("Connecting to %s ", ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {

      delay(500);

      Serial.print(".");

  }

  Serial.println(" CONNECTED");

  

  //init and get the time

  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);

  printLocalTime();

 

  //disconnect WiFi as it's no longer needed

  WiFi.disconnect(true);

  WiFi.mode(WIFI_OFF);

}

 

void loop()

{

  delay(1000);

  printLocalTime();

}

از آنجایی که این برنامه باید به اینترنت متصل شود، باید کد را با WIFI SSID و گذر واژه‌ی خود ویرایش کنید.

محاسبه‌ی جبران GMT و Daylight Offset

برای اینکه ساعت را به منطقه‌ی زمانی محلی خود تنظیم کنید، باید دو مقدار برای آن تنظیم کنید که به موقعیت مکانی شما بستگی دارد.

·         GMT Offset: تعداد ثانیه‌های منطقه‌ی زمانی شما با GMT متفاوت است. این می‌تواند یک مقدار مثبت یا منفی باشد.

·         Daylight Offset: اگر منطقه‌ی شما زمان تابستانی را رعایت می‌کند، این تعداد ثانیه‌هایی است که ساعت را برای DST پیش می‌برید.

برای محاسبه‌ی جابه‌جایی GTM باید بدانید که منطقه‌ی زمانی شما از ساعت گرینویچ چند ساعت جبران شده‌است. شما احتمالاً از قبل این مقدار را می‌دانید اما اگر اطلاعی ندارید، می‌توانید محاسبه کنید. اگر در شرق رصدخانه‌ی گرینویچ هستید، این مقدار مثبت و اگر در قسمت غربی یعنی آمریکای شمالی و جنوبی زندگی می‌کنید، این مقدار منفی است.

در مرحله‌ی بعدی باید این رقم را به ثانیه تبدیل کنید. به این معنا که باید آن را در ۳۶۰۰ ضرب کنید زیرا ۳۶۰۰ ثانیه در یک ساعت وجود دارد. نتیجه‌ی آن جابه‌جایی GTM است که در خط ۸ کد وارد خواهیدکرد. من منطقه‌ی خود را به‌عنوان مثال استفاه می‌کنم. من در ایران که در زمان شرقی است زندگی می‌کنم. جبران GTM ما    ساعت است.

پس از ویرایش کد با پارامترهای WIFI، تمام کاری که شما باید انجام دهید این ست که کد را در ESP32 بارگذاری کنید، سریال مانیتور را باز کرده و تنظیم مجدد را فشار دهید.

باید ببینید ESP32 به WIFI شما متصل است و سپس هر ثانیه زمان را نمایش دهید. از آنجا که اکثر رایانه‌ها با سرور زمان اینترنت همگام‌سازی می‌شوند، مقدار زمان باید با مقدار رایانه‌ی شما مطابقت داشته‌باشد.

سنسور هال

سنسور هال (Hall Sensor) دستگاهی است که از هال افکت برای تشخیص یک میدان مغناطیسی استفاده می‌کند. ESP32 دارای یک سنسور Hall Effect یکپارچه است. بنابراین می‌توانید از آن برای تشخیص وجود (یا عدم وجود) یک میدان مغناطیسی استفاده کنید. کد زیر نحوه‌ی خواندن مقدار سنسور یکپارچه‌ی Hall را نشان می‌دهد.

//Simple sketch to access the internal hall effect detector on the esp32.

//values can be quite low. 

//Brian Degger / @sctv  

 

int val = 0;

void setup() {

  Serial.begin(9600);

    }

 

void loop() {

  // put your main code here, to run repeatedly:

  val = hallRead();

  // print the results to the serial monitor:

  //Serial.print("sensor = ");

  Serial.println(val);//to graph 

}

 

این کد به راحتی کد blink است و در واقع از برخی از جهات حتی ساده‌تر است. تابع hallRead() تمام کارها را انجام می‌دهد و یک مقدار صحیح تولید می‌کند که خروجی سنسور را نشان می‌دهد. فقط کافی است این کد را در ESP32 بارگذاری کنید، سریال مانیتور را باز کنید (توجه داشته باشید که این کد برخلاف سایر موارد با ۹۶۰۰  Boud اجراء می‌شود ) و تنظیم مجدد را فشار دهید. شما یک رشته اعداد دریافت خواهیدکرد. حالا یک آهنربا را نزدیک ماژول ESP32 بیاورید و اعداد را مشاهده کنید. هنگام نزدیک شدن آهنربا به سنسور باید متوجه تغییر مشخصی شوید.

برای یک تجربه‌ی بصری بیشتر، به جای سریال مانیتور، Serial Plotter را باز کنید. باید گرافی را مشاهده کنید که به وجود یا عدم وجود آهنربا شما پاسخ دهد.

کمرنگ‌شدن نرم‌افزار LED

تغییر روشنایی LED یک کار کاملاً محبوب برای میکروکنترلر است. با استفاده از آردوینو از تابع analogWrite استفاده می‌کنیم که یک خروجی PWM (مدولاسیون عرض پالس) به پایه‌های خروجی فعال‌شده با PWM فراهم می‌کند. متفاوت بودن چرخه‌ی کار سیگنال PWM، این است که روشنایی LED را کنترل می‌کند. با این‌حال، analogWrite در ESP32 کار نمی‌کند. درعوض ما نیاز به استفاده از روش دیگری برای کنترل روشنایی LED داریم. ESP32 دارای ۱۶ کانال داخلی برای کنترل روشنایی LED است. شما می‌توانید دقت تایمر PWM و فرکانس آن را کنترل کرده که این کار به شما امکان کنترل دقیق روشنایی LED را می‌دهد.

/*

 LEDC Software Fade

 

 This example shows how to software fade LED

 using the ledcWrite function.

 

 Code adapted from original Arduino Fade example:

 https://www.arduino.cc/en/Tutorial/Fade

 

 This example code is in the public domain.

 */

 

// use first channel of 16 channels (started from zero)

#define LEDC_CHANNEL_0     0

 

// use 13 bit precission for LEDC timer

#define LEDC_TIMER_13_BIT  13

 

// use 5000 Hz as a LEDC base frequency

#define LEDC_BASE_FREQ     5000

 

// fade LED PIN (replace with LED_BUILTIN constant for built-in LED)

#define LED_PIN            5

 

int brightness = 0;    // how bright the LED is

int fadeAmount = 5;    // how many points to fade the LED by

 

// Arduino like analogWrite

// value has to be between 0 and valueMax

void ledcAnalogWrite(uint8_t channel, uint32_t value, uint32_t valueMax = 255) {

  // calculate duty, 8191 from 2 ^ 13 - 1

  uint32_t duty = (8191 / valueMax) * min(value, valueMax);

 

  // write duty to LEDC

  ledcWrite(channel, duty);

}

 

void setup() {

  // Setup timer and attach timer to a led pin

  ledcSetup(LEDC_CHANNEL_0, LEDC_BASE_FREQ, LEDC_TIMER_13_BIT);

  ledcAttachPin(LED_PIN, LEDC_CHANNEL_0);

}

 

void loop() {

  // set the brightness on LEDC channel 0

  ledcAnalogWrite(LEDC_CHANNEL_0, brightness);

 

  // change the brightness for next time through the loop:

  brightness = brightness + fadeAmount;

 

  // reverse the direction of the fading at the ends of the fade:

  if (brightness <= 0 || brightness >= 255) {

    fadeAmount = -fadeAmount;

  }

  // wait for 30 milliseconds to see the dimming effect

  delay(30);

}

برای کار با اتصال ESP32 باید ثابت LED_PIN (در خط ۲۳) را از “۵” به “۲” تغییر دهید زیرا LED به GPIO2 متصل است. توجه داشته‌باشید گه این طرح تابعی به‌نام ledcAnalogWrite را تعریف می‌کند که به روشی مشابه عملکرد analogWrite آردوینو است. ممکن است بخواهید از آن در برنامه‌هایی که برای کنترل LEDها ایجاد می‌کنید، استفاده کنید.

تکرار تایمر

مثال تکرار تایمر در اصل یک کرونومتر اساسی است. با فشاردادن دکمه‌ی  Reset (ENABLE) در ماژول ESP32، شمارش ثانیه‌ها شروع می‌شود که برروی سریال مانیتور نمایش داده‌می‌شوند. شمارش تا زمان فشاردادن دکمه‌ی فشار در ماژول ادامه خواهدداشت.

/*

 Repeat timer example

 

 This example shows how to use hardware timer in ESP32. The timer calls onTimer

 function every second. The timer can be stopped with button attached to PIN 0

 (IO0).

 

 This example code is in the public domain.

 */

 

// Stop button is attached to PIN 0 (IO0)

#define BTN_STOP_ALARM    0

 

hw_timer_t * timer = NULL;

volatile SemaphoreHandle_t timerSemaphore;

portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED;

 

volatile uint32_t isrCounter = 0;

volatile uint32_t lastIsrAt = 0;

 

void IRAM_ATTR onTimer(){

  // Increment the counter and set the time of ISR

  portENTER_CRITICAL_ISR(&timerMux);

  isrCounter++;

  lastIsrAt = millis();

  portEXIT_CRITICAL_ISR(&timerMux);

  // Give a semaphore that we can check in the loop

  xSemaphoreGiveFromISR(timerSemaphore, NULL);

  // It is safe to use digitalRead/Write here if you want to toggle an output

}

 

void setup() {

  Serial.begin(115200);

 

  // Set BTN_STOP_ALARM to input mode

  pinMode(BTN_STOP_ALARM, INPUT);

 

  // Create semaphore to inform us when the timer has fired

  timerSemaphore = xSemaphoreCreateBinary();

 

  // Use 1st timer of 4 (counted from zero).

  // Set 80 divider for prescaler (see ESP32 Technical Reference Manual for more

  // info).

  timer = timerBegin(0, 80, true);

 

  // Attach onTimer function to our timer.

  timerAttachInterrupt(timer, &onTimer, true);

 

  // Set alarm to call onTimer function every second (value in microseconds).

  // Repeat the alarm (third parameter)

  timerAlarmWrite(timer, 1000000, true);

 

  // Start an alarm

  timerAlarmEnable(timer);

}

 

void loop() {

  // If Timer has fired

  if (xSemaphoreTake(timerSemaphore, 0) == pdTRUE){

    uint32_t isrCount = 0, isrTime = 0;

    // Read the interrupt count and time

    portENTER_CRITICAL(&timerMux);

    isrCount = isrCounter;

    isrTime = lastIsrAt;

    portEXIT_CRITICAL(&timerMux);

    // Print it

    Serial.print("onTimer no. ");

    Serial.print(isrCount);

    Serial.print(" at ");

    Serial.print(isrTime);

    Serial.println(" ms");

  }

  // If button is pressed

  if (digitalRead(BTN_STOP_ALARM) == LOW) {

    // If timer is still running

    if (timer) {

      // Stop and free timer

      timerEnd(timer);

      timer = NULL;

    }

  }

}

 

مثال RepeatTimer در زیر منوی Timer است و نحوه‌ی ایجاد یک کنترل‌کننده‌ی وقفه برای ESP32 را نشان‌می‌دهد. کنترل‌کننده‌ی وقفه، عملکردی به‌نام onTimer است که به تایمر متصل‌شده و هر ثانیه فعال می‌شود.

دکمه در حلقه‌ی LOOP طرح خوانده می‌شود و برای متوقف‌کردن تایمر، عملکرد داخلی timerEnd را فراخوانی می‌کند.